'------------------------------------------------------------
' Module:   HTTP.VBS
'
' Purpose:  Utility functions for implementing HTTP communication from the client
'
' Author:   David Rubin
'           Adapted from AICC_CLIENT.VBS
' Date:     10/23/02
'------------------------------------------------------------


' Function: xmlHTTPAvail
'
' Purpose:  Determine if XMLHTTP component is installed
'
'
Function xmlHTTPAvail()
	Dim objHttp

	On Error Resume Next
	xmlHTTPAvail = True
	Set objHttp = CreateObject("Microsoft.XMLHTTP")
	If Err.number <> 0 Then
		Err.Clear
		Set objHttp = CreateObject("MSXML2.XMLHTTP")
	End If
	If Err.number <> 0 Then
		xmlHTTPAvail = False
	End If
	Set objHttp = Nothing
End Function

' Function: xmlHTTPPost
'
' Purpose:  POST a form to a web page and retrieve the result
'
Function xmlHTTPPost(strURL, strData)
	Dim objHttp

	On Error Resume Next
	xmlHTTPPost = ""
	Set objHttp = CreateObject("Microsoft.XMLHTTP")
	If Err.number <> 0 Then
		Err.Clear
		Set objHttp = CreateObject("MSXML2.XMLHTTP")
	End If
	If Err.number <> 0 Then
		MsgBox "Error creating XMLHTTP object"
		Err.Clear
		Exit Function
	End If
	objHttp.Open "POST", strURL, False
	If Err.number <> 0 Then
		MsgBox "Error " & Hex(Err.number) & " connecting to server:" & vbCrLf & Err.description
		Err.Clear
		Set objHttp = Nothing
		Exit Function
	End If
	objHttp.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
	objHttp.setRequestHeader "User-Agent", "Mozilla Compatible (MS IE 3.01 WinNT)"
	objHttp.Send strData
	If Err.number <> 0 Then
		MsgBox "Error " & Hex(Err.number) & " sending to server:" & vbCrLf & Err.description
		Err.Clear
	Else
		xmlHTTPPost = objHttp.responseText
	End If
	Set objHttp = Nothing
End Function